nix-configs/flake.nix

{
  description = "I have no idea what I'm doing";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs";
    apple-silicon = {
      url = "github:tpwrules/nixos-apple-silicon";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    flake-utils.url = "github:numtide/flake-utils";
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nix-darwin = {
      url = "github:nix-darwin/nix-darwin/master";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nur = {
      url = "github:nix-community/NUR";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    sops-nix = {
      url = "github:mic92/sops-nix";
      inputs.nix.follows = "nixpkgs";
    };
  };
  outputs =
    {
      self,
      nixpkgs,
      apple-silicon,
      flake-utils,
      home-manager,
      nix-darwin,
      nur,
      sops-nix,
    }@inputs:
    let
      supportedSystems = [
        "x86_64-linux"
        "aarch64-darwin"
        "aarch64-linux"
      ];
      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
      overlays = [
        apple-silicon.overlays.apple-silicon-overlay
        nur.overlays.default
      ];
    in
    {
      nixosConfigurations = {
        laptop = nixpkgs.lib.nixosSystem {
          system = "x86_64-linux";
          modules = [
            ./nixos/common.nix
            ./nixos/hosts/laptop/default.nix
            ./nixos/hosts/laptop/hardware-configuration.nix
          ];
        };
        homeserver = nixpkgs.lib.nixosSystem {
          system = "aarch64-linux";
          modules = [
            ./nixos/common.nix
            ./nixos/hosts/homeserver/default.nix
            ./nixos/hosts/homeserver/hardware-configuration.nix
            apple-silicon.nixosModules.apple-silicon-support
          ];
          specialArgs = inputs;
        };
      };
      homeConfigurations = nixpkgs.lib.foldl' (
        acc: system:
        acc
        // {
          "irl-${system}" = home-manager.lib.homeManagerConfiguration {
            pkgs = import nixpkgs {
              inherit system overlays;
            };
            modules = [
              ./home/irl.nix
            ];
          };
          "irl-gui-${system}" = home-manager.lib.homeManagerConfiguration {
            pkgs = import nixpkgs {
              inherit system overlays;
            };
            modules = [
              ./home/irl.nix
              {
                irl.gui-packages = true;
              }
            ];
          };
        }
      ) { } supportedSystems;
    }
    // flake-utils.lib.eachSystem supportedSystems (system: {
      formatter = nixpkgs.legacyPackages.${system}.nixfmt-tree;
    })
    // {
      darwinConfigurations."irl-mac-mini" = nix-darwin.lib.darwinSystem {
        system = "aarch64-darwin";
        modules = [
          ./darwin/common.nix
        ];
      };
    };
}