nix-configs/flake.nix

{
  description = "I have no idea what I'm doing";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs";
    flake-utils.url = "github:numtide/flake-utils";
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nur = {
      url = "github:nix-community/NUR";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
  outputs =
    {
      nixpkgs,
      flake-utils,
      home-manager,
      nur,
      ...
    }:
    let
      supportedSystems = [
        "x86_64-linux"
        "aarch64-darwin"
        "aarch64-linux"
      ];
      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
    in
    {
      nixosConfigurations = {
        laptop = nixpkgs.lib.nixosSystem {
          system = "x86_64-linux";
          modules = [
            ./nixos/common.nix
            ./nixos/hosts/laptop/default.nix
            ./nixos/hosts/laptop/hardware-configuration.nix
          ];
        };
      };
      homeConfigurations = nixpkgs.lib.foldl' (
        acc: system:
        acc
        // {
          "irl-${system}" = home-manager.lib.homeManagerConfiguration {
            pkgs = import nixpkgs {
              inherit system;
              overlays = [ nur.overlay ];
            };
            modules = [ ./home/irl.nix ];
          };
          "irl-gui-${system}" = home-manager.lib.homeManagerConfiguration {
            pkgs = import nixpkgs {
              inherit system;
              overlays = [ nur.overlay ];
            };
            modules = [
              ./home/irl.nix
              {
                irl.gui-packages = true;
              }
            ];
          };
        }
      ) { } supportedSystems;
    }
    // flake-utils.lib.eachSystem supportedSystems (system: {
      formatter = nixpkgs.legacyPackages.${system}.nixfmt-rfc-style;
    });
}